MS Outlook attachment redirect

[Putt4Dough]

Hi everyone.

I'm a newbie here so please be gentle.

At the office we are changing from Eudora to Outlook.

With Eudora we had an option that automatically drop every attachment to a windows folder without any manual intervention.

With Outlook I can't find any option. All emails coming in has the email attached to the email thus stored in the PST file. Is there an option that would save the attachment to a default windows folder? This would save my users tones of work since they receive tones of attachment per day.

TY
Mike

 

[KSoD]

There is no default option to do this. You have to right click the file and click the save as option.

 

[Lexluethar]

IF you control the exchange server that these emails are going through you may be able to 'filter' the attachements that way and place them in a folder.

But as Mak said, there is no option within Outlook that would do this for your users - there may be a 3rd party add-on to do it. But Outlook doesn't do this out-of-the-box.

 

[Putt4Dough]

I'm not using Exchange server.

I found an add-on. Actually two programs that manage attachment (outlookattremover-setup.exe and Office Sniffer) but they don't do it automatically when the email comes in.

Does anyone know an add-on that would de this procedure automatically?

TY
Mike

 

[Hefemeister]

Every solution I am seeing is accomplishing this via VBA.
auto save attachments outlook - Google Search

Take a look at some of these threads.

 

[Putt4Dough]

Thank you Hefemeister.

It took some fiddling around but I got a script to work. Here is my contribution to configure this option:

1. From Outlook, open the VBEditor (Alt+F11)
2. Click Tools>References select MS Outlook and click OK
3. Paste the code into the ThisOutlookSession module from the left project window
4. Create a directory "C:\download" (or amend the constant: FILE_PATH to eqaul an existing folder)
5. Save the project
6. Close and Restart Outlook (Voilà, all download attachments will be copied to your C:\download folder)

Script:

'###############################################################################
 '### Module level Declarations
 'expose the items in the target folder to events
Option Explicit
Dim WithEvents TargetFolderItems As Items
 'set the string constant for the path to save attachments
Const FILE_PATH As String = "C:\download\"
 
 '###############################################################################
 '### this is the Application_Startup event code in the ThisOutlookSession module
Private Sub Application_Startup()
     'some startup code to set our "event-sensitive" items collection
    Dim ns As Outlook.NameSpace
     '
    Set ns = Application.GetNamespace("MAPI")
    Set TargetFolderItems = ns.Folders.Item( _
    "Personal Folders").Folders.Item("Inbox TX").Items
     
End Sub
 
 '###############################################################################
 '### this is the ItemAdd event code
Sub TargetFolderItems_ItemAdd(ByVal Item As Object)
     'when a new item is added to our "watched folder" we can process it
    Dim olAtt As Attachment
    Dim i As Integer
     
    If Item.Attachments.Count > 0 Then
        For i = 1 To Item.Attachments.Count
            Set olAtt = Item.Attachments(i)
             'save the attachment
            olAtt.SaveAsFile FILE_PATH & olAtt.FileName
           
        Next
    End If
     
    Set olAtt = Nothing
     
End Sub
 
 '###############################################################################
 '### this is the Application_Quit event code in the ThisOutlookSession module
Private Sub Application_Quit()
     
    Dim ns As Outlook.NameSpace
    Set TargetFolderItems = Nothing
    Set ns = Nothing
     
End Sub